/*
 * Copyright 2018 the original author or authors.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

package org.gradle.cache.internal.locklistener

import spock.lang.Specification

import static org.gradle.cache.internal.locklistener.FileLockPacketType.LOCK_RELEASE_CONFIRMATION
import static org.gradle.cache.internal.locklistener.FileLockPacketType.UNKNOWN

class FileLockPacketPayloadTest extends Specification {

    def "encodes lock id and type"() {
        when:
        def bytes = FileLockPacketPayload.encode(42, LOCK_RELEASE_CONFIRMATION)

        then:
        bytes.length == FileLockPacketPayload.MAX_BYTES
        bytes == [1, 0, 0, 0, 0, 0, 0, 0, 42, 3] as byte[]
    }

    def "decodes payloads without type"() {
        when:
        def payload = FileLockPacketPayload.decode([1, 0, 0, 0, 0, 0, 0, 0, 42, 1] as byte[], 9)

        then:
        payload.lockId == 42
        payload.type == UNKNOWN
    }

    def "decodes payloads with type #type"() {
        when:
        def payload = FileLockPacketPayload.decode([1, 0, 0, 0, 0, 0, 0, 0, 42, type.ordinal()] as byte[], 10)

        then:
        payload.lockId == 42
        payload.type == type

        where:
        type << FileLockPacketType.values()
    }

    def "decodes payloads with unknown types that might be added in the future"() {
        when:
        def payload = FileLockPacketPayload.decode([1, 0, 0, 0, 0, 0, 0, 0, 42, FileLockPacketType.values().length] as byte[], 10)

        then:
        payload.lockId == 42
        payload.type == UNKNOWN
    }
}
